**Macro**

directory = getDirectory("Choose a Directory "); // prompts for directory with the images

list = getFileList(directory);

// for-loop below processes the files in the specified folder and outputs the quantification results in a table that can be copy/pasted into Excel

for (i=0; i<list.length; i++) {

path = directory+list[i];

showProgress(i, list.length);

// "run(...)" command below opens complex images, such as ones generated by AxioVision; use just "open(path)" for simple images

run("Bio-Formats Importer", "open=path autoscale color\_mode=Default view=Hyperstack stack\_order=XYCZT");

if (nImages>=1) {

imagename = list[i];

run("Split Channels"); // splits a multi-channel image into indiviual images fro processing and assigns channels numbers, such as C1, C2

selectImage("C1-"+imagename); // assume C1 is the f-actin stain image

close(); // close f-actin-stain image, as only interested in quantifying nuclei

selectImage("C2-"+imagename); // assume C2 is the nucleus-stain image

run("8-bit"); // image is converted to 8-bit for compatiblity with some of the following functions

run("Median...", "radius=2"); // smooths the image, making thresholded areas more uniform

run("Subtract Background...", "rolling=50"); // subtracts background fluorescence, hue, etc; set rolling ball radius to optimize the amount of background removed

run("Auto Threshold", "method=IsoData show"); // run an automatic thresholding algorithm, as less concerned about nucleus area

run("Convert to Mask"); // creates the binary black-white image based on the threshold values calculated automatically

run("Watershed"); // use watershed algorithm to separate multiple nuclei that appear to be merged into one large particle

// command below sets quantification categories: area, standard deviation, and percent coverage of nuclei

run("Set Measurements...", "area standard area\_fraction redirect=None decimal=2");

// command below extract the categories defined above for the thresholded nuclei; adjust particle size accordingly - for example use 10 um2>dead cells<100um2 & 1000>live cell>150um2

run("Analyze Particles...", "size=25-1000 circularity=0.00-1.00 show=Nothing display summarize");

selectImage("C2-"+imagename);

close();

} else

print("Error opening "+path); // outputs an error if the specific folder of images cannot be opened

}

**Representative output**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Slice | Count | Total Area | Average Size | Area Fraction |
| C2-250C-1-0127.zvi | 126 | 13476.39 | 106.96 | 2.4 |
| C2-250C-1-0128.zvi | 251 | 31042.63 | 123.68 | 5.5 |
| C2-250C-1-0129.zvi | 187 | 19590.56 | 104.76 | 3.5 |
| C2-250C-1-0130.zvi | 100 | 10525.28 | 105.25 | 1.9 |